home *** CD-ROM | disk | FTP | other *** search
/ PC World 2007 January / PCWorld_2007-01_cd.bin / v cisle / hotkey / AutoHotkey104504_Install.exe / AutoHotkey.chm / docs / scripts / winlirc.ahk < prev    next >
Text File  |  2006-11-15  |  12KB  |  280 lines
  1. ; WinLIRC Client
  2. ; http://www.autohotkey.com
  3. ; This script receives notifications from WinLIRC whenever you press
  4. ; a button on your remote control. It can be used to automate Winamp,
  5. ; Windows Media Player, etc. It's easy to configure. For example, if
  6. ; WinLIRC recognizes a button named "VolUp" on your remote control,
  7. ; create a label named VolUp and beneath it use the command
  8. ; "SoundSet +5" to increase the soundcard's volume by 5%.
  9.  
  10. ; Here are the steps to use this script:
  11. ; 1) Configure WinLIRC to recognize your remote control and its buttons.
  12. ;    WinLIRC is at http://winlirc.sourceforge.net
  13. ; 2) Edit the WinLIRC path, address, and port in the CONFIG section below.
  14. ; 3) Launch this script. It will start the WinLIRC server if needed.
  15. ; 4) Press some buttons on your remote control. A small window will
  16. ;    appear showing the name of each button as you press it.
  17. ; 5) Configure your buttons to send keystrokes and mouse clicks to
  18. ;    windows such as Winamp, Media Player, etc. See the examples below.
  19.  
  20. ; This script requires AutoHotkey 1.0.38 or later.
  21. ; HISTORY OF CHANGES
  22. ; October 5, 2005:
  23. ; - Eliminated Winsock warning dialog "10054" upon system shutdown/logoff.
  24. ; - Added option "DelayBetweenButtonRepeats" to throttle the repeat speed.
  25.  
  26. ; -------------------------------------------------
  27. ; CONFIGURATION SECTION: Set your preferences here.
  28. ; -------------------------------------------------
  29. ; Some remote controls repeat the signal rapidly while you're holding down
  30. ; a button. This makes it difficult to get the remote to send only a single
  31. ; signal. The following setting solves this by ignoring repeated signals
  32. ; until the specified time has passed. 200 is often a good setting.  Set it
  33. ; to 0 to disable this feature.
  34. DelayBetweenButtonRepeats = 200
  35.  
  36. ; Specify the path to WinLIRC, such as C:\WinLIRC\winlirc.exe
  37. WinLIRC_Path = %A_ProgramFiles%\WinLIRC\winlirc.exe
  38.  
  39. ; Specify WinLIRC's address and port. The most common are 127.0.0.1 (localhost) and 8765.
  40. WinLIRC_Address = 127.0.0.1
  41. WinLIRC_Port = 8765
  42.  
  43. ; Do not change the following two lines. Skip them and continue below.
  44. Gosub WinLIRC_Init
  45. return
  46.  
  47. ; --------------------------------------------
  48. ; ASSIGN ACTIONS TO THE BUTTONS ON YOUR REMOTE
  49. ; --------------------------------------------
  50. ; Configure your remote control's buttons below. Use WinLIRC's names
  51. ; for the buttons, which can be seen in your WinLIRC config file
  52. ; (.cf file) -- or you can press any button on your remote and the
  53. ; script will briefly display the button's name in a small window.
  54. ; 
  55. ; Below are some examples. Feel free to revise or delete them to suit
  56. ; your preferences.
  57.  
  58. VolUp:
  59. SoundSet +5  ; Increase master volume by 5%.
  60. return
  61.  
  62. VolDown:
  63. SoundSet -5  ; Reduce master volume by 5%.
  64. return
  65.  
  66. ChUp:
  67. WinGetClass, ActiveClass, A
  68. if ActiveClass in Winamp v1.x,Winamp PE  ; Winamp is active.
  69.     Send {right}  ; Send a right-arrow keystroke.
  70. else  ; Some other type of window is active.
  71.     Send {WheelUp}  ; Rotate the mouse wheel up by one notch.
  72. return
  73.  
  74. ChDown:
  75. WinGetClass, ActiveClass, A
  76. if ActiveClass in Winamp v1.x,Winamp PE  ; Winamp is active.
  77.     Send {left}  ; Send a left-arrow keystroke.
  78. else  ; Some other type of window is active.
  79.     Send {WheelDown}  ; Rotate the mouse wheel down by one notch.
  80. return
  81.  
  82. Menu:
  83. IfWinExist, Untitled - Notepad
  84. {
  85.     WinActivate
  86. }
  87. else
  88. {
  89.     Run, Notepad
  90.     WinWait, Untitled - Notepad
  91.     WinActivate
  92. }
  93. Send Some keystrokes sent to Notepad.{Enter}
  94. return
  95.  
  96. ; The examples above give a feel for how to accomplish common tasks.
  97. ; To learn the basics of AutoHotkey, check out the Quick-start Tutorial
  98. ; at http://www.autohotkey.com/docs/Tutorial.htm
  99.  
  100. ; ----------------------------
  101. ; END OF CONFIGURATION SECTION
  102. ; ----------------------------
  103. ; Do not make changes below this point unless you want to change the core
  104. ; functionality of the script.
  105.  
  106. WinLIRC_Init:
  107. OnExit, ExitSub  ; For connection cleanup purposes.
  108.  
  109. ; Launch WinLIRC if it isn't already running:
  110. Process, Exist, winlirc.exe
  111. if not ErrorLevel  ; No PID for WinLIRC was found.
  112. {
  113.     IfNotExist, %WinLIRC_Path%
  114.     {
  115.         MsgBox The file "%WinLIRC_Path%" does not exist. Please edit this script to specify its location.
  116.         ExitApp
  117.     }
  118.     Run %WinLIRC_Path%
  119.     Sleep 200  ; Give WinLIRC a little time to initialize (probably never needed, just for peace of mind).
  120. }
  121.  
  122. ; Connect to WinLIRC (or any type of server for that matter):
  123. socket := ConnectToAddress(WinLIRC_Address, WinLIRC_Port)
  124. if socket = -1  ; Connection failed (it already displayed the reason).
  125.     ExitApp
  126.  
  127. ; Find this script's main window:
  128. Process, Exist  ; This sets ErrorLevel to this script's PID (it's done this way to support compiled scripts).
  129. DetectHiddenWindows On
  130. ScriptMainWindowId := WinExist("ahk_class AutoHotkey ahk_pid " . ErrorLevel)
  131. DetectHiddenWindows Off
  132.  
  133. ; When the OS notifies the script that there is incoming data waiting to be received,
  134. ; the following causes a function to be launched to read the data:
  135. NotificationMsg = 0x5555  ; An arbitrary message number, but should be greater than 0x1000.
  136. OnMessage(NotificationMsg, "ReceiveData")
  137.  
  138. ; Set up the connection to notify this script via message whenever new data has arrived.
  139. ; This avoids the need to poll the connection and thus cuts down on resource usage.
  140. FD_READ = 1     ; Received when data is available to be read.
  141. FD_CLOSE = 32   ; Received when connection has been closed.
  142. if DllCall("Ws2_32\WSAAsyncSelect", "UInt", socket, "UInt", ScriptMainWindowId, "UInt", NotificationMsg, "Int", FD_READ|FD_CLOSE)
  143. {
  144.     MsgBox % "WSAAsyncSelect() indicated Winsock error " . DllCall("Ws2_32\WSAGetLastError")
  145.     ExitApp
  146. }
  147. return
  148.  
  149.  
  150.  
  151. ConnectToAddress(IPAddress, Port)
  152. ; This can connect to most types of TCP servers, not just WinLIRC.
  153. ; Returns -1 (INVALID_SOCKET) upon failure or the socket ID upon success.
  154. {
  155.     VarSetCapacity(wsaData, 32)  ; The struct is only about 14 in size, so 32 is conservative.
  156.     result := DllCall("Ws2_32\WSAStartup", "UShort", 0x0002, "UInt", &wsaData) ; Request Winsock 2.0 (0x0002)
  157.     ; Since WSAStartup() will likely be the first Winsock function called by this script,
  158.     ; check ErrorLevel to see if the OS has Winsock 2.0 available:
  159.     if ErrorLevel
  160.     {
  161.         MsgBox WSAStartup() could not be called due to error %ErrorLevel%. Winsock 2.0 or higher is required.
  162.         return -1
  163.     }
  164.     if result  ; Non-zero, which means it failed (most Winsock functions return 0 upon success).
  165.     {
  166.         MsgBox % "WSAStartup() indicated Winsock error " . DllCall("Ws2_32\WSAGetLastError")
  167.         return -1
  168.     }
  169.  
  170.     AF_INET = 2
  171.     SOCK_STREAM = 1
  172.     IPPROTO_TCP = 6
  173.     socket := DllCall("Ws2_32\socket", "Int", AF_INET, "Int", SOCK_STREAM, "Int", IPPROTO_TCP)
  174.     if socket = -1
  175.     {
  176.         MsgBox % "socket() indicated Winsock error " . DllCall("Ws2_32\WSAGetLastError")
  177.         return -1
  178.     }
  179.  
  180.     ; Prepare for connection:
  181.     SizeOfSocketAddress = 16
  182.     VarSetCapacity(SocketAddress, SizeOfSocketAddress)
  183.     InsertInteger(2, SocketAddress, 0, AF_INET)   ; sin_family
  184.     InsertInteger(DllCall("Ws2_32\htons", "UShort", Port), SocketAddress, 2, 2)   ; sin_port
  185.     InsertInteger(DllCall("Ws2_32\inet_addr", "Str", IPAddress), SocketAddress, 4, 4)   ; sin_addr.s_addr
  186.  
  187.     ; Attempt connection:
  188.     if DllCall("Ws2_32\connect", "UInt", socket, "UInt", &SocketAddress, "Int", SizeOfSocketAddress)
  189.     {
  190.         MsgBox % "connect() indicated Winsock error " . DllCall("Ws2_32\WSAGetLastError") . ". Is WinLIRC running?"
  191.         return -1
  192.     }
  193.     return socket  ; Indicate success by returning a valid socket ID rather than -1.
  194. }
  195.  
  196.  
  197.  
  198. ReceiveData(wParam, lParam)
  199. ; By means of OnMessage(), this function has been set up to be called automatically whenever new data
  200. ; arrives on the connection.  It reads the data from WinLIRC and takes appropriate action depending
  201. ; on the contents.
  202. {
  203.     socket := wParam
  204.     ReceivedDataSize = 4096  ; Large in case a lot of data gets buffered due to delay in processing previous data.
  205.     Loop  ; This loop solves the issue of the notification message being discarded due to thread-already-running.
  206.     {
  207.         VarSetCapacity(ReceivedData, ReceivedDataSize, 0)  ; 0 for last param terminates string for use with recv().
  208.         ReceivedDataLength := DllCall("Ws2_32\recv", "UInt", socket, "Str", ReceivedData, "Int", ReceivedDataSize, "Int", 0)
  209.         if ReceivedDataLength = 0  ; The connection was gracefully closed, probably due to exiting WinLIRC.
  210.             ExitApp  ; The OnExit routine will call WSACleanup() for us.
  211.         if ReceivedDataLength = -1
  212.         {
  213.             WinsockError := DllCall("Ws2_32\WSAGetLastError")
  214.             if WinsockError = 10035  ; WSAEWOULDBLOCK, which means "no more data to be read".
  215.                 return 1
  216.             if WinsockError <> 10054 ; WSAECONNRESET, which happens when WinLIRC closes via system shutdown/logoff.
  217.                 ; Since it's an unexpected error, report it.  Also exit to avoid infinite loop.
  218.                 MsgBox % "recv() indicated Winsock error " . WinsockError
  219.             ExitApp  ; The OnExit routine will call WSACleanup() for us.
  220.         }
  221.         ; Otherwise, process the data received. Testing shows that it's possible to get more than one line
  222.         ; at a time (even for explicitly-sent IR signals), which the following method handles properly.
  223.         ; Data received from WinLIRC looks like the following example (see the WinLIRC docs for details):
  224.         ; 0000000000eab154 00 NameOfButton NameOfRemote
  225.         Loop, parse, ReceivedData, `n, `r
  226.         {
  227.             if A_LoopField in ,BEGIN,SIGHUP,END  ; Ignore blank lines and WinLIRC's start-up messages.
  228.                 continue
  229.             ButtonName =  ; Init to blank in case there are less than 3 fields found below.
  230.             Loop, parse, A_LoopField, %A_Space%  ; Extract the button name, which is the third field.
  231.                 if A_Index = 3
  232.                     ButtonName := A_LoopField
  233.             global DelayBetweenButtonRepeats  ; Declare globals to make them available to this function.
  234.             static PrevButtonName, PrevButtonTime, RepeatCount  ; These variables remember their values between calls.
  235.             if (ButtonName != PrevButtonName || A_TickCount - PrevButtonTime > DelayBetweenButtonRepeats)
  236.             {
  237.                 if IsLabel(ButtonName)  ; There is a subroutine associated with this button.
  238.                     Gosub %ButtonName%  ; Launch the subroutine.
  239.                 else ; Since there is no associated subroutine, briefly display which button was pressed.
  240.                 {
  241.                     if (ButtonName == PrevButtonName)
  242.                         RepeatCount += 1
  243.                     else
  244.                         RepeatCount = 1
  245.                     SplashTextOn, 150, 20, Button from WinLIRC, %ButtonName% (%RepeatCount%)
  246.                     SetTimer, SplashOff, 3000  ; This allows more signals to be processed while displaying the window.
  247.                 }
  248.                 PrevButtonName := ButtonName
  249.                 PrevButtonTime := A_TickCount
  250.             }
  251.         }
  252.     }
  253.     return 1  ; Tell the program that no further processing of this message is needed.
  254. }
  255.  
  256.  
  257.  
  258. SplashOff:
  259. SplashTextOff
  260. SetTimer, SplashOff, Off
  261. return
  262.  
  263.  
  264.  
  265. InsertInteger(pInteger, ByRef pDest, pOffset = 0, pSize = 4)
  266. ; The caller must ensure that pDest has sufficient capacity.  To preserve any existing contents in pDest,
  267. ; only pSize number of bytes starting at pOffset are altered in it.
  268. {
  269.     Loop %pSize%  ; Copy each byte in the integer into the structure as raw binary data.
  270.         DllCall("RtlFillMemory", "UInt", &pDest + pOffset + A_Index-1, "UInt", 1, "UChar", pInteger >> 8*(A_Index-1) & 0xFF)
  271. }
  272.  
  273.  
  274.  
  275. ExitSub:  ; This subroutine is called automatically when the script exits for any reason.
  276. ; MSDN: "Any sockets open when WSACleanup is called are reset and automatically
  277. ; deallocated as if closesocket was called."
  278. DllCall("Ws2_32\WSACleanup")
  279. ExitApp
  280.